build.gradle

/////////////////////////////
// BuildScript and Plugins //
/////////////////////////////

buildscript {
    repositories {
        jcenter()
        maven {
            name 'Forge'
            url 'http://files.minecraftforge.net/maven'
        }
    }
    dependencies {
        classpath(group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '3.+', changing: true) {
            exclude group: 'trove', module: 'trove'
        }
    }
}

plugins {
    id 'org.jetbrains.kotlin.jvm' version "$kotlin_version"
    id "com.github.hierynomus.license" version "0.15.0"
    id 'com.github.johnrengelman.shadow' version '4.0.4'
}

apply plugin: 'net.minecraftforge.gradle'

configurations {
    embed
    compile.extendsFrom embed
}

//////////////////
// Dependencies //
//////////////////

repositories {
    mavenCentral()
    maven {
        url 'https://files.minecraftforge.net/maven'
    }
    maven {
        url 'https://minecraft.curseforge.com/api/maven/'
    }
}

dependencies {
    minecraft group: 'net.minecraftforge', name: 'forge', 'version': "$minecraft_version-$forge_version"

    compile group: 'kottle', name: 'Kottle', 'version': kottle_version
}

minecraft {
    mappings channel: 'snapshot', version: forge_mappings

    runs {
        client {
            properties 'forge.logging.markers': 'REGISTRIES,REGISTRYDUMP'
            properties 'forge.logging.console.level': 'debug'
            properties 'fml.earlyprogresswindow': 'false'
            mods {
                makro {
                    source sourceSets.main
                }
            }
        }
    }
}

///////////////
// Artifacts //
///////////////

tasks {
    compileKotlin {
        kotlinOptions.jvmTarget = "1.8"
    }
    compileTestKotlin {
        kotlinOptions.jvmTarget = "1.8"
    }
}

version = "$minecraft_version-$mod_version"

processResources {
    inputs.property "version", project.version

    from(sourceSets.main.resources.srcDirs) {
        include 'META-INF/mods.toml'
        expand 'version':project.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

shadowJar {
    classifier = ''

    configurations = [project.configurations.embed]
}

tasks.build.dependsOn shadowJar

reobf {
    shadowJar {}
}

task deobfJar(type: Jar) {
    from sourceSets.main.output
            classifier = 'deobf'
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allJava
            classifier = 'sources'
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives deobfJar
    archives sourcesJar
    archives javadocJar
}


///////////////
// Licencing //
///////////////

license {
    include "**/*.kt"
}