build.gradle

apply plugin: 'groovy'

sourceSets {
    jobs {
        groovy {
            srcDirs 'jobs'
        }
    }
}

repositories {
    mavenCentral()
    jcenter()
    maven { url 'https://repo.jenkins-ci.org/releases/' }
}

dependencies {
    compile 'org.codehaus.groovy:groovy:2.1.3'
    compile 'org.jenkins-ci.plugins:job-dsl-core:1.58'
    compile 'org.jenkins-ci.plugins:job-dsl:1.58'
    compile 'org.reflections:reflections:0.9.10'
    compile group: 'org.slf4j', name: 'slf4j-simple', version: '1.7.24'

    compile group: 'org.apache.commons', name: 'commons-io', version: '1.3.2'
    compile group: 'javax.servlet', name: 'servlet-api', version: '2.5'
    compile group: 'com.googlecode.java-diff-utils', name: 'diffutils', version: '1.2'

    testCompile('org.spockframework:spock-core:0.7-groovy-2.0') {
        exclude module: 'groovy-all'
    }

    // for the RestApiScriptRunner
    compile('org.codehaus.groovy.modules.http-builder:http-builder:0.7.2') {
        exclude(module: 'groovy')
    }

    // for the RestApiScriptRunner and XmlOutputRunner
    compile('ant:ant:1.7.0')

    // for evaluating plugin version constraints
    compile group: 'com.udojava', name: 'EvalEx', version: '1.0'
    
    compile 'org.yaml:snakeyaml:1.14'
}

tasks.getByName('test').inputs.files(sourceSets.jobs.groovy.srcDirs)

task rest(dependsOn: 'classes', type: JavaExec) {
    main = 'com.base2.rest.RestApiScriptRunner'
    classpath = sourceSets.main.runtimeClasspath
    systemProperties System.getProperties()
}

task jenkins(dependsOn: 'classes', type: JavaExec) {
  main = 'com.base2.ciinabox.JobSeeder'
  classpath = sourceSets.main.runtimeClasspath
  systemProperties System.getProperties()
}

task jobsScriptCompare(dependsOn: 'classes', type: JavaExec) {
    main = 'com.base2.ciinabox.ScriptCompare'
    classpath = sourceSets.main.runtimeClasspath
    systemProperties System.getProperties()
}

task debugXml(dependsOn: 'classes', type: JavaExec) {
    main = 'com.base2.debug.XmlOutputRunner'
    classpath = sourceSets.main.runtimeClasspath
    systemProperties System.getProperties()
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.4'
}